「山竹」電子氣墊彈珠台

const int L0 = 46;  // fan led ''

const int L1 = 47;

const int L2 = 48;

const int L3 = 49;

const int L4 = 50;

const int L5 = 51;

const int L6 = 52;

const int L7 = 53;  // fan led ''

const int S0_0 = 22;  // score indicators 0 ''

const int S0_1 = 23;

const int S0_2 = 24;

const int S0_3 = 25;

const int S0_4 = 26;  // score indicators 0 ''

const int S1_0 = 31;  // score indicators 1 ''

const int S1_1 = 32;

const int S1_2 = 33;

const int S1_3 = 34;

const int S1_4 = 35;  // score indicators 1 ''

const int Fans = 13;  // Fan (SSR) control

const int S0 = 44;  // Left start button

const int S1 = 45;  // Right start button

const int Laser0 = 42;  // Left laser diode

const int Laser1 = 43;  // Right laser diode

const int vr = A0;

const int Spins[22] = {S0_0, S0_1, S0_2, S0_3, S0_4, S1_4, S1_3, S1_2, S1_1, S1_0, S1_0, S1_0, S1_1, S1_2, S1_3, S1_4, S0_4, S0_3, S0_2, S0_1, S1_0, S1_0};

const int Lpins[10] = {L7, L0, L1, L6, L3, L4, L5, L2, L7, L0};

const int S0pins[5] = {S0_0, S0_1, S0_2, S0_3, S0_4};

const int S1pins[5] = {S1_0, S1_1, S1_2, S1_3, S1_4};

const char startSound[3] = {0x02, 0x03, 0x04};

const char rb_win[2] = {0x08, 0x09};

bool _60sw; bool _30sw; bool _10sw;

bool endState;

bool isDraw;

int vrValue;

unsigned long timeLimit;

unsigned long startTime;

int winSide;

bool restartState = true;

bool startState = false;

int score0 = 0;

int score1 = 0;

bool hitState0 = false;

bool hitState1 = false;

// var

const int scoreFlashDelayTime = 77;

const int ledDelayTimes[5] = {500, 200, 100, 350, 250};

int ledDelayTime;

const char volume = 0x15;  // MP3 volume (00~1E)

const unsigned long limits[3] = {60e3, 120e3, 180e3};

// MP3

unsigned char mp3_setvol[5] = {0x7e, 0x03, 0x31, volume, 0xef};

unsigned char mp3_stop[4] = {0x7e, 0x02, 0x0e, 0xef};

unsigned char mp3_sd[5] = {0x7e, 0x03, 0x35, 0x01, 0xef};

unsigned char mp3_single[5] = {0x7e, 0x03, 0x33, 0x04, 0xef};

void setup() {

  pinMode(L0, OUTPUT);

  pinMode(L1, OUTPUT);

  pinMode(L2, OUTPUT);

  pinMode(L3, OUTPUT);

  pinMode(L4, OUTPUT);

  pinMode(L5, OUTPUT);

  pinMode(L6, OUTPUT);

  pinMode(L7, OUTPUT);

  pinMode(Fans, OUTPUT);

  pinMode(S0, INPUT_PULLUP);

  pinMode(S1, INPUT_PULLUP);

  pinMode(S0_0, OUTPUT);

  pinMode(S0_1, OUTPUT);

  pinMode(S0_2, OUTPUT);

  pinMode(S0_3, OUTPUT);

  pinMode(S0_4, OUTPUT);

  pinMode(S1_0, OUTPUT);

  pinMode(S1_1, OUTPUT);

  pinMode(S1_2, OUTPUT);

  pinMode(S1_3, OUTPUT);

  pinMode(S1_4, OUTPUT);

  pinMode(Laser0, INPUT);

  pinMode(Laser1, INPUT);

  pinMode(vr, INPUT);

  // Serial3

  Serial3.begin(9600);

  Serial3.write(mp3_sd, 5);

  delay(500);

  Serial3.write(mp3_setvol, 5);

  Serial3.write(mp3_single, 5);

}

void loop() {

  if (restartState) {  // restart

    Serial3.write(mp3_stop, 4);

    digitalWrite(Fans, LOW);

    ledDelayTime = ledDelayTimes[0];

    _60sw = true; _30sw = true; _10sw = true;

    score0 = 0; score1 = 0;

    clearScore();

    ledAll(LOW);

    startState = false; endState = false;

    hitState0 = false; hitState1 = false;

    while (true) {  // waiting for buttons

      if (digitalRead(S0) == LOW && !startState) {

        scoreLedAll(0, LOW); scoreLedAll(1, LOW);

        for (int i = 0; i < 50; i++) {

          if (digitalRead(S1) == LOW) { startState = true; break; }

          delay(100); scoreLedControl(true, 0);

        }

      }

      if (digitalRead(S1) == LOW && !startState) {

        scoreLedAll(0, LOW); scoreLedAll(1, LOW);

        for (int i = 0; i < 50; i++) {

          if (digitalRead(S0) == LOW) { startState = true; break; }

          delay(100); scoreLedControl(true, 1);

        }

      }

      scoreLedControl(false, 0);

      if (startState) {

        scoreLedAll(0, LOW); scoreLedAll(1, LOW);

        vrValue = map(analogRead(vr), 0, 1023, 0, 2);

        timeLimit = limits[vrValue];

        restartState = false; startState = false;

        digitalWrite(Fans, HIGH);

        delay(2000);

        // on

        mp3_play(0x00, startSound[vrValue]);

        startTime = millis();

        break;

      }

    }

  }

  if (_60sw || _30sw || _10sw) {

    if (millis() - startTime > timeLimit - 60e3 && timeLimit > 60e3 && _60sw) {  // 60 seconds warning

      mp3_play(0x00, 0x05);

      _60sw = false;

    }

    else if (millis() - startTime > timeLimit - 30e3 && timeLimit > 30e3 && _30sw) {  // 30 seconds warning

      mp3_play(0x00, 0x06);

      ledDelayTime = ledDelayTimes[1];

      ledAll(LOW);

      _30sw = false;

    }

    else if (millis() - startTime > timeLimit - 10e3 && timeLimit > 10e3 && _10sw) {  // 10 seconds warning

      mp3_play(0x00, 0x07);

      ledDelayTime = ledDelayTimes[2];

      ledAll(LOW);

      _10sw = false;

    }

  }

  if (millis() - startTime > timeLimit) {  // time's up

    endState = true; isDraw = false;

    if (score0 > score1) { winSide = 0; }

    else if (score1 > score0) { winSide = 1; }

    else { isDraw = true; }

  }

  if (!digitalRead(Laser1) && !hitState0) {  // 0 scoring

    hitState0 = true;

    digitalWrite(S0pins[score0++], HIGH);

    mp3_play(0x00, 0x01);  // sound ding

  }

  if (!digitalRead(Laser0) && !hitState1) {  // 1 scoring

    hitState1 = true;

    digitalWrite(S1pins[score1++], HIGH);

    mp3_play(0x00, 0x01);  // sound ding

  }

  if (hitState0 && digitalRead(Laser1)) { hitState0 = false; }

  if (hitState1 && digitalRead(Laser0)) { hitState1 = false; }

  if ((score0 >= 5) || (score1 >= 5)) {

    endState = true;

    winSide = (int)score1 >= 5;

    isDraw = false;

    }

  if (score0 == 4) { score0Flash(); ledDelayTime = ledDelayTimes[2]; ledAll(LOW); }

  if (score1 == 4) { score1Flash(); ledDelayTime = ledDelayTimes[2]; ledAll(LOW); }

  if (endState) {  // end

    for (int i = 0; i < score0; i++) { digitalWrite(S0pins[i], HIGH); }

    for (int i = 0; i < score1; i++) { digitalWrite(S1pins[i], HIGH); }

    delay(234);

    // sound end

    if (!isDraw) {

      mp3_play(0x00, rb_win[winSide]);

      for (int i = 0; i < 5; i++) { ledWave(winSide + 2, 70); delay(100); }

    }

    else { mp3_play(0x00, 0x0a); }

    ledAll(LOW); delay(100);

    for (int i = 0; i < 2; i++) { ledAll(HIGH); delay(200); ledAll(LOW); delay(200); }

    ledAll(HIGH); delay(1000);

    restartState = true;

    score0 = 0; score1 = 0;

    delay(2000);

  }

  ledControl();

}

void scoreLedAll(int side, int val) {

  for (int i = 0; i < 5; i++) {

    if (side == 0) { digitalWrite(S0pins[i], val); }

    if (side == 1) { digitalWrite(S1pins[i], val); }

    }

}

void scoreLedControl(int isPushed, int side) {

  if (!isPushed) {

    unsigned long timeindex = (millis() / ledDelayTimes[3]) % 22;

    digitalWrite(Spins[timeindex], HIGH);

    if (timeindex == 10 || timeindex == 21) { scoreLedAll(0, LOW); scoreLedAll(1, LOW); }  

  }

  else {

    unsigned long timeindex = (millis() / ledDelayTimes[4]) % 2;

    scoreLedAll(side, timeindex);

  }

}

void ledControl() {

  unsigned long timeindex = ((millis() / ledDelayTime) % 4) * 2;

  digitalWrite(Lpins[timeindex],  LOW); digitalWrite(Lpins[++timeindex],  LOW); digitalWrite(Lpins[++timeindex],  HIGH); digitalWrite(Lpins[++timeindex],  HIGH);

}

void ledAll(int val) {

  for (int i = 0; i < 8; i++) {

    digitalWrite(Lpins[i], val);

  }

}

void ledWave(int s, int dur) {

  ledAll(LOW);

  for (int i = s; i < 10; i += 2) {

    digitalWrite(Lpins[i], HIGH); delay(dur);

  }

}

void score0Flash() {

  unsigned long timeindex = ((millis() / scoreFlashDelayTime) % 10);

  if (timeindex == 0 || timeindex == 2 || timeindex == 4) {

    digitalWrite(S0pins[0], LOW); digitalWrite(S0pins[1], LOW); digitalWrite(S0pins[2], LOW); digitalWrite(S0pins[3], LOW);

  }

  else {

    digitalWrite(S0pins[0], HIGH); digitalWrite(S0pins[1], HIGH); digitalWrite(S0pins[2], HIGH); digitalWrite(S0pins[3], HIGH);

  }

}

void score1Flash() {

  unsigned long timeindex = ((millis() / scoreFlashDelayTime) % 10);

  if (timeindex == 0 || timeindex == 2 || timeindex == 4) {

    digitalWrite(S1pins[0], LOW); digitalWrite(S1pins[1], LOW); digitalWrite(S1pins[2], LOW); digitalWrite(S1pins[3], LOW);

  }

  else {

    digitalWrite(S1pins[0], HIGH); digitalWrite(S1pins[1], HIGH); digitalWrite(S1pins[2], HIGH); digitalWrite(S1pins[3], HIGH);

  }

}

void clearScore() {

  for (int i = 0; i < 5; i++) {

    digitalWrite(S0pins[i], LOW); digitalWrite(S1pins[i], LOW);

  }

}

void mp3_play(char indexlow, char indexhigh) {

  unsigned char mp3_songplay[6] = {0x7e, 0x04, 0x41, indexlow, indexhigh, 0xef};

  Serial3.write(mp3_songplay, 6);

}